Esempio: misurazione e ripresa di isola rettangolare

Esecuzione del programma

  • Sgrossatura isola rettangolare con 0,5 di sovrametallo
  • Misurazione isola rettangolare
  • Finitura isola rettangolare tenendo conto dei valori misurati

0 BEGIN PGM TOUCHPROBE MM

1 TOOL CALL 5 Z S6000

; Chiamata utensile prelavorazione

2 Q1 = 81

; Lunghezza rettangolo in X (quota di sgrossatura)

3 Q2 = 61

; Lunghezza rettangolo in Y (quota di sgrossatura)

4 L Z+100 R0 FMAX M3

; Disimpegno utensile

5 CALL LBL 1

; Chiamata sottoprogramma di lavorazione

6 L Z+100 R0 FMAX

; Disimpegno utensile

7 TOOL CALL 600 Z

; Chiamata sistema di tastatura

8 TCH PROBE 424 MIS. RETTAN. ESTERNO ~

Q273=+50

;CENTRO 1. ASSE ~

Q274=+50

;CENTRO 2. ASSE ~

Q282=+80

;LUNGHEZZA 1. LATO ~

Q283=+60

;LUNGHEZZA 2. LATO ~

Q261=-5

;ALTEZZA MISURATA ~

Q320=+0

;DISTANZA SICUREZZA ~

Q260=+30

;ALTEZZA DI SICUREZZA ~

Q301=+0

;SPOST. A ALT. SICUR. ~

Q284=+0

;LIMITE MAX LATO PRIM ~

Q285=+0

;LIM. MIN. LATO PRIM. ~

Q286=+0

;LIM. MAX LATO SECON. ~

Q287=+0

;MIN. LIMITE 2. LATO ~

Q279=+0

;TOLLERANZA 1. CENTRO ~

Q280=+0

;TOLLERANZA 2. CENTRO ~

Q281=+0

;PROTOCOLLO DI MIS. ~

Q309=+0

;STOP PGM SE ERRORE ~

Q330=+0

;UTENSILE

9 Q1 = Q1 - Q164

; Calcolo lunghezza in X in base all'offset misurato

10 Q2 = Q2 - Q165

; Calcolo lunghezza in Y in base all'offset misurato

11 L Z+100 R0 FMAX

; Disimpegno sistema di tastatura

12 TOOL CALL 25 Z S8000

; Chiamata utensile finitura

13 L Z+100 R0 FMAX M3

; Disimpegno utensile

14 CALL LBL 1

; Chiamata sottoprogramma di lavorazione

15 L Z+100 R0 FMAX

16 M30

; Fine programma

17 LBL 1

; Sottoprogramma con ciclo di lavorazione Isola rettangolare

18 CYCL DEF 256 ISOLA RETTANGOLARE ~

Q218=+Q1

;LUNGHEZZA 1. LATO ~

Q424=+82

;QUOTA PEZZO GREZZO 1 ~

Q219=+Q2

;LUNGHEZZA 2. LATO ~

Q425=+62

;QUOTA PEZZO GREZZO 2 ~

Q220=+0

;RAGGIO / SMUSSO ~

Q368=+0.1

;QUOTA LATERALE CONS. ~

Q224=+0

;ANGOLO DI ROTAZIONE ~

Q367=+0

;POSIZIONE ISOLA ~

Q207=+500

;AVANZAM. FRESATURA ~

Q351=+1

;MODO FRESATURA ~

Q201=-10

;PROFONDITA ~

Q202=+5

;PROF. INCREMENTO ~

Q206=+3000

;AVANZ. INCREMENTO ~

Q200=+2

;DISTANZA SICUREZZA ~

Q203=+10

;COORD. SUPERFICIE ~

Q204=+20

;2. DIST. SICUREZZA ~

Q370=+1

;SOVRAPP.TRAIET.UT. ~

Q437=+0

;POSIZIONE DI AVVICINAMENTO ~

Q215=+0

;TIPO LAVORAZIONE ~

Q369=+0

;PROFONDITA' CONSEN. ~

Q338=+20

;INCREMENTO FINITURA ~

Q385=+500

;AVANZAMENTO FINITURA

19 L X+50 Y+50 R0 FMAX M99

; Chiamata ciclo

20 LBL 0

; Fine sottoprogramma

21 END PGM TOUCHPROBE MM