Ejemplo: Torneado simultáneo

En el siguiente programa NC, se utilizan los ciclos 882 TORNEADO CON DESBASTE SIMULTANEO y 883 GIRAR ACABADO SIMULTANEO.

Ejecución del programa

  • Llamar a la herramienta, p. ej. TURN_ROUGH
  • Activar modo de torneado
  • Posicionamiento previo
  • Seleccionar contorno con SEL CONTOUR
  • Ciclo 882 TORNEADO CON DESBASTE SIMULTANEO
  • Llamar al ciclo para su ejecución
  • Llamada de herramienta: p. ej., TURN_FINISH
  • Activar modo de torneado
  • Ciclo 883 GIRAR ACABADO SIMULTANEO
  • Llamar al ciclo para su ejecución
  • Final del programa

0 BEGIN PGM 1341941_1 MM

1 BLK FORM ROTATION Z DIM_D FILE "1341941_blank.H"

2 FUNCTION MODE TURN

; Activar torneado

3 TOOL CALL "TURN_ROUGH"

; Llamada de herramienta

4 CYCL DEF 800 ADAP. SIST. ROTATIVO ~

Q497=+0

;ANGULO DE PRECESION ~

Q498=+0

;INVERTIR HERRAMIENTA ~

Q530=+2

;MECANIZADO INICIADO ~

Q531=+1

;ANGULO DE INCIDENCIA ~

Q532=MAX

;AVANCE ~

Q533=-1

;DIREC. PEFER. ~

Q535=+3

;TORNEADO EXCENTRICO ~

Q536=+0

;EXCENTR. SIN PARADA ~

Q599=+0

;RETIRADA

5 FUNCTION TURNDATA SPIN VCONST: ON VC:400 SMAX800

; Velocidad de corte constante

6 M145

; Reiniciar el offset de la herramienta

7 FUNCTION TCPM F TCP AXIS POS PATHCTRL AXIS REFPNT TIP-CENTER

; Activar TCPM

8 L X+120 Y+0 R0 FMAX

; Posicionamiento previo

9 L Z+20 R0 FMAX M303

10 FUNCTION TURNDATA BLANK "1341941_blank.H"

; Seguimiento de la pieza en bruto

11 SEL CONTOUR "1341941_finish.h"

; Definir el contorno

12 CYCL DEF 882 TORNEADO CON DESBASTE SIMULTANEO ~

Q460=+2

;DISTANCIA DE SEGURIDAD ~

Q499=+0

;INVERTIR CONTORNO ~

Q558=-90

;INIC. CONT.ANG.PROL. ~

Q559=+90

;FIN CONT. ANG. PROL. ~

Q478=+0.3

;AVANCE DESBASTE ~

Q488=+0.3

;AVANCE PROFUND. ~

Q556=-80

;DIST. ANG. DE INCID. ~

Q557=+90

;MAX. ANG. INCIDENCIA ~

Q567=+0.4

;SOBREMED. ACAB. CONT ~

Q519=+2

;AJUSTE ~

Q463=+2.5

;MAX. PROF. CORTE ~

Q590=+1

;MODO DE MECANIZADO ~

Q591=+0

;SECUENCIA MECANIZADO ~

Q389=+0

;UNI.-BIDIRECCIONAL

13 CYCL CALL

; Llamada al ciclo

14 M305

15 TOOL CALL "TURN_FINISH"

; Llamada de herramienta

16 CYCL DEF 800 ADAP. SIST. ROTATIVO ~

Q497=+0

;ANGULO DE PRECESION ~

Q498=+0

;INVERTIR HERRAMIENTA ~

Q530=+2

;MECANIZADO INICIADO ~

Q531=+1

;ANGULO DE INCIDENCIA ~

Q532=MAX

;AVANCE ~

Q533=+1

;DIREC. PEFER. ~

Q535=+3

;TORNEADO EXCENTRICO ~

Q536=+0

;EXCENTR. SIN PARADA ~

Q599=+0

;RETIRADA

17 FUNCTION TURNDATA SPIN VCONST: ON VC:400 SMAX800

; Velocidad de corte constante

18 M145

; Reiniciar el offset de la herramienta

19 FUNCTION TCPM F TCP AXIS POS PATHCTRL AXIS REFPNT TIP-CENTER

; Activar TCPM

20 L X+120 Y+0 R0 FMAX

21 L Z+20 R0 FMAX M303

22 CYCL DEF 883 GIRAR ACABADO SIMULTANEO ~

Q460=+2

;DISTANCIA DE SEGURIDAD ~

Q499=+0

;INVERTIR CONTORNO ~

Q558=-90

;INIC. CONT.ANG.PROL. ~

Q559=+90

;FIN CONT. ANG. PROL. ~

Q505=+0.2

;AVANCE ACABADO ~

Q556=-80

;DIST. ANG. DE INCID. ~

Q557=+90

;MAX. ANG. INCIDENCIA ~

Q555=+1

;PASO ANGULAR ~

Q537=+0

;ANG. INCIDEN. ACTIVO ~

Q538=+0

;ANG. INCIDEN. INICIO ~

Q539=+0

;ANG. INCIDEN. FINAL ~

Q565=+0

;ANG.INCID.FIN CONT ~

Q566=+0

;SOBREMED. ACABADO Z ~

Q567=+0

;SOBREMED. ACAB. CONT

23 CYCL CALL

; Llamada al ciclo

24 M305

25 FUNCTION TURNDATA BLANK OFF

; Desactivar seguimiento de la pieza en bruto

26 CYCL DEF 801 RESET SISTEMA ROTATIVO

27 FUNCTION MODE MILL

; Activar modo de fresado

28 TOOL CALL 0 Z

29 PLANE RESET TURN FMAX

30 M30

; Final del programa

31 END PGM 1341941_1 MM

Programa NC 1341941_blank.h

0 BEGIN PGM 1341941_BLANK MM

1 L X+0 Z+0.4

2 L X+80

3 L Z-139.6

4 L X+0

5 L Z+0.4

6 END PGM 1341941_BLANK MM

Programa NC 1341941_finish.h

0 BEGIN PGM 1341941_FINISH MM

1 L X+0 Z+0 RR

2 CR Z-65.136 X+15 R+33 DR+

3 RND R2

4 L Z-86

5 RND R10

6 L X+78 Z-95

7 RND R5

8 L Z-100

9 END PGM 1341941_FINISH MM