Komplex konturformel

Grunder

Med de komplexa konturformlerna kan du sätta samman komplexa konturer av delkonturer (fickor eller öar). De individuella delkonturerna (geometridata) anger man i form av separata NC-program. Därigenom kan alla delkonturer återanvändas godtyckligt. Styrsystemet beräknar den sammansatta konturen utifrån de utvalda delkonturerna, vilka man kopplar ihop via en konturformel.

sl_contform_depth
Schema: Arbeta med SL-cykler och komplex konturformel

0 BEGIN CONT MM

...

5 SEL CONTOUR "MODEL"

6 CYCL DEF 20 KONTURDATA

...

8 CYCL DEF 21 URFRAESNING

...

9 CYCL CALL

...

13 CYCL DEF 23 FINSKAER DJUP

...

14 CYCL CALL

...

16 CYCL DEF 24 FINSKAER SIDA

...

17 CYCL CALL

...

50 L Z+250 R0 FMAX M2

51 END PGM CONT MM

 
Tip
  • Programmeringsanvisning:
  • Minnet för en SL-cykel (alla konturbeskrivningsprogram) är begränsat till maximalt 128 konturer . Antalet möjliga konturelement beror på konturtypen (invändig eller utvändig kontur) samt antalet konturbeskrivningar och motsvarar maximalt 16384 konturelement.
  • SL-cykler med konturformel förutsätter en strukturerad programuppbyggnad och erbjuder möjlighet att placera återkommande konturer i individuella NC-program. Via konturformeln kopplar man ihop delkonturerna till en samlad kontur och bestämmer om det handlar om en ficka eller en ö.
  • Delkonturernas egenskaper
  • Styrsystemet känner igen alla konturer som fickor, programmera inte någon radiekompensering
  • Styrsystemet ignorerar matning F och tilläggsfunktioner M
  • Koordinatomräkning är tillåten.– Om de programmeras inom delkonturerna, är de även verksamma i efterföljande NC-program, och behöver inte återställas efter cykelanropet.
  • De anropade NC-programmen får även innehålla koordinater i spindelaxeln, de ignoreras dock.
  • Bearbetningsplanet fastläggs i det anropade NC-programmets första koordinatblock
  • Vid behov kan du programmera delkonturer med olika djup
  • Cyklernas egenskaper
  • Styrsystemet positionerar automatiskt verktyget till säkerhetsavståndet före varje cykel
  • Varje djupnivå fräses utan lyftning av verktyget eftersom fräsningen sker runt öar
  • Radien på ”Innerhörn” kan programmeras – verktyget stannar inte, fräsmärken undviks (gäller för den yttersta verktygsbanan vid urfräsning och finskär sida)
  • Vid finskär sida förflyttar styrsystemet verktyget till konturen på en tangentiellt anslutande cirkelbåge
  • Även vid djupfinbearbetning förflyttar styrsystemet verktyget till arbetsstycket på en tangentiellt anslutande cirkelbåge (till exempel spindelaxel Z: cirkelbåge i planet Z/X)
  • Styrsystemet bearbetar konturen genomgående med medfräsning eller motfräsning

Måttuppgifterna för bearbetningen såsom fräsdjup, tilläggsmått och säkerhetsavstånd anges centralt i cykel 20 KONTURDATA eller 271 OCM KONTURDATA.

Schema: Beräkning av delkonturer med konturformel

0 BEGIN MODEL MM

1 DECLARE CONTOUR QC1 = ”120”

2 DECLARE CONTOUR QC2 = ”121” DEPTH15

3 DECLARE CONTOUR QC3 = ”122” DEPTH10

4 DECLARE CONTOUR QC4 = ”123” DEPTH5

5 QC10 = ( QC1 | QC3 | QC4 )\QC2

6 END PGM MODEL MM

0 BEGIN PGM 120 MM

1 CC X+75 Y+50

2 LP PR+45 PA+0

3 CP IPA+360 DR+

4 END PGM 120 MM

0 BEGIN PGM 121 MM

...

Välj NC-program med konturdefinition

Med funktionen SEL CONTOUR väljer du ett NC-program med konturdefinitioner som styrsystemet hämtar konturbeskrivningarna från:

Gör på följande sätt:

SF_4_NCFunktion_Einfuegen

  1. Välj Infoga NC-funktion
  2. Styrsystemet öppnar fönstret Infoga NC-funktion.
SelectContour

  1. Välj SEL CONTOUR
  2. Styrsystemet startar inmatningen av konturformeln.
  3. Definiera konturen

Styrsystemet erbjuder följande alternativ för inmatning av konturen:

Selekteringsmöjligheter

Funktion

Fil

  • Inmatning
  • Filval

Definiera namnet på konturen eller välj Filval

QS

Definiera en strängparameters nummer

 
Tip
  • Programmeringsanvisning:
  • Om den anropade filen finns i samma katalog som den anropande filen, kan du även koppla endast filnamnet utan sökväg.
  • Programmera SEL CONTOUR-blocket före SL-cyklerna. Cykel 14 KONTUR behövs inte längre vid användning av SEL CONTUR.

Definiera en konturbeskrivning

Med funktionen DECLARE CONTOUR anger man i ett NC-program sökvägen till andra NC-program som styrsystemet ska hämta konturbeskrivningarna från. Dessutom kan du välja ett separat djup för den här konturbeskrivningen.

Gör på följande sätt:

SF_4_NCFunktion_Einfuegen

  1. Välj Infoga NC-funktion
  2. Styrsystemet öppnar fönstret Infoga NC-funktion.

  1. Välj DECLARE CONTOUR
  2. Styrsystemet startar inmatningen av konturformeln.
  3. Ange numret på konturbeskrivningen QC
  4. Definiera en konturbeskrivning

Styrsystemet erbjuder följande alternativ för inmatning av konturen:

Selekteringsmöjligheter

Funktion

Fil

  • Inmatning
  • Filval

Definiera namnet på konturen eller välj Filval

QS

Definiera en strängparameters nummer

 
Tip
  • Programmeringsanvisning:
  • Med de angivna konturbeteckningarna QC kan man kombinera olika konturer med varandra i konturformeln.
  • Om den anropade filen finns i samma katalog som den anropande filen, kan du även koppla endast filnamnet utan sökväg.
  • Om du använder konturer med separata djup, måste du tilldela alla delkonturerna ett djup (tilldela i förekommande fall djupet 0).
  • Olika djup (DEPTH) ingår endast i överlappande element. Det är inte fallet med rena öar inne i en ficka. Använd i så fall den enkla konturformeln.
  • Enkel konturformel

Ange komplex konturformel

Med funktionen Konturformel kan du kombinera olika konturer i en matematisk formel:

SF_4_NCFunktion_Einfuegen

  1. Välj Infoga NC-funktion
  2. Styrsystemet öppnar fönstret Infoga NC-funktion.

  1. Välj Konturformel QC
  2. Styrsystemet startar inmatningen av konturformeln.
  3. Ange numret på konturbeskrivningen QC
  4. Ange konturformel

Hjälpbild

Inmatning

Kopplingsfunktion

Exempel

8H000166

&

Snitt

QC10 = QC1 & QC5

8H000164

|

Union

QC25 = QC7 | QC18

Konturformel_Funktion3

^

Union, men utan snitt

QC12 = QC5 ^ QC25

8H000165

\

Utan

QC25 = QC1 \ QC2

(

Vänster parentes

QC12 = QC1 & (QC2 | QC3)

)

Höger parentes

QC12 = QC1 & (QC2 | QC3)

Definiera enstaka kontur

QC12 = QC1

Överlagrade konturer

8H000164

Styrsystemet betraktar en programmerad kontur som en ficka. Med funktionerna i konturformeln har man möjlighet att omvandla en kontur till en ö.

Man kan överlagra fickor och öar för att skapa en ny kontur. Därigenom kan en fickas yta ökas med en överlagrad ficka eller minskas med en överlagrad ö.

Underprogram: Överlappande fickor

 
Tip

Följande programexempel är konturbeskrivningsprogram som definieras i ett konturdefinitionsprogram. Konturdefinitionsprogrammet kallas i sin tur upp via funktionen SEL CONTOUR i det egentliga huvudprogrammet.

Fickan A och B överlappar varandra.

Styrsystemet beräknar skärningspunkterna S1 och S2. Du behöver inte programmera dem själv.

Fickorna har programmerats som fullcirklar.

Konturbeskrivningsprogram 1: Ficka A

0 BEGIN PGM POCKET MM

1 L X+10 Y+50 R0

2 CC X+35 Y+50

3 C X+10 Y+50 DR-

4 END PGM POCKET MM

Konturbeskrivningsprogram 2: Ficka B

0 BEGIN PGM POCKET2 MM

1 L X+90 Y+50 R0

2 CC X+65 Y+50

3 C X+90 Y+50 DR-

4 END PGM POCKET2 MM

”Summa”-yta

8H000164

Båda delytorna A och B inklusive den gemensamt överlappade ytan skall bearbetas:

  • Ytorna A och B måste vara programmerade i separata NC-program utan radiekompensering
  • I konturformeln beräknas ytorna A och B med funktionen ”förenad med”.

Konturdefinitionsprogram:

* - ...

21 DECLARE CONTOUR QC1 = "POCKET.H"

22 DECLARE CONTOUR QC2 = "POCKET2.H"

23 QC10 = QC1 | QC2

* - ...

”Differens”-yta

8H000165

Ytan A skall bearbetas förutom den av B överlappade delen:

  • Ytorna A och B måste vara programmerade i separata NC-program utan radiekompensering
  • I konturformeln subtraheras yta B från yta A med funktionen utan.

Konturdefinitionsprogram:

* - ...

21 DECLARE CONTOUR QC1 = "POCKET.H"

22 DECLARE CONTOUR QC2 = "POCKET2.H"

23 QC10 = QC1 \ QC2

* - ...

”Snitt”-yta

8H000166

Den av A och B överlappade ytan skall bearbetas. (Ytor som bara täcks av en ficka skall lämnas obearbetade.)

  • Ytorna A och B måste vara programmerade i separata NC-program utan radiekompensering
  • I konturformeln beräknas ytorna A och B med funktionen ”avskuren med”.

Konturdefinitionsprogram:

* - ...

21 DECLARE CONTOUR QC1 = "POCKET.H"

22 DECLARE CONTOUR QC2 = "POCKET2.H"

23 QC10 = QC1 & QC2

* - ...

Bearbetning av kontur med SL- eller OCM-cykler

 
Tip

Bearbetningen av den definierade sammansatta konturen sker med SL-cyklerna eller OCM-cyklerna (se Översikt).