Primer: kartezične funkcije poti

V uporabniškem priročniku vsebovani NC-programi so predlogi rešitev. Preden na stroju uporabite NC-programe ali posamezne NC-nize, jih morate prilagoditi.

  • Prilagodite naslednje vsebine:
  • Orodja
  • Podatki o rezanju
  • Pomiki
  • Varna višina ali varni položaji
  • Položaji, značilni za stroje, npr. z M91
  • Poti priklicev programov

Nekateri NC-programi so odvisni od kinematike stroja. Te NC-programe pred prvim testnim delovanjem prilagodite vaši kinematiki stroja.

NC-programe dodatno testiranje s pomočjo simulacije dejanskega programskega teka.

 
Tip

S pomočjo programskega testa ugotovite, ali lahko NC-programe uporabljate z razpoložljivimi možnostmi programske opreme, aktivno kinematiko stroja in trenutno konfiguracijo stroja.

0 BEGIN PGM CIRCULAR MM

1 BLK FORM 0.1 Z X+0 Y+0 Z-20

2 BLK FORM 0.2 X+100 Y+100 Z+0

; definicija surovca za simulacijo obdelave

3 TOOL CALL 1 Z S4000

; priklic orodja z orodno osjo in številom vrtljajev vretena

4 L Z+250 R0 FMAX

; odmik orodja na orodni osi v hitrem teku FMAX

5 L X-10 Y-10 R0 FMAX

; predpozicioniranje orodja

6 L Z-5 R0 F1000 M3

; premik na obdelovalno globino s pomikom F = 1000 mm/min

7 APPR LCT X+5 Y+5 R5 RL F300

; krožni primik na točko 1 konture s tangencialnim nadaljevanjem

8 L X+5 Y+85

; programiranje prve premice za kot 2

9 RND R10 F150

; programiranje zaokroževanja z R = 10 mm, pomik F = 150 mm/min

10 L X+30 Y+85

; primik na točko 3: začetna točka krožnice CR

11 CR X+70 Y+95 R+30 DR-

; primik na točko 4: končna točka krožnice CR s polmerom R = 30 mm

12 L X+95

; primik na točko 5

13 L X+95 Y+40

; primik na točko 6: začetna točka krožnice CT

14 CT X+40 Y+5

; primik na točko 7: končna točka krožnice CT; krožni lok s tangencialnim nadaljevanjem na točki 6; krmiljenje samodejno izračuna polmer

15 L X+5

; primik na zadnjo konturno točko 1

16 DEP LCT X-20 Y-20 R5 F1000

; odmik od konture na krožnici s tangencialnim nadaljevanjem

17 L Z+250 R0 FMAX M2

; odmik orodja, konec programa

18 END PGM CIRCULAR MM