Formulă de contur complexa

Noţiuni fundamentale

Prin utilizarea formulelor de contur complexe puteţi combina mai multe subcontururi (buzunare sau insule) pentru a programa contururi complexe. Definiţi subcontururile individuale (date geometrice) ca programe NC separate. Astfel, orice subcontur poate fi utilizat de mai multe ori. Sistemul de control calculează conturul complet din subcontururile selectate, pe care le legaţi printr-o formulă de contur.

Structura programului: Prelucrare cu cicluri CAN şi formule de contur complexe

0 BEGIN CONT MM

...

5 SEL CONTOUR "MODEL"

6 CYCL DEF 20 DATE CONTUR

...

8 CYCL DEF 21 DEGROSARE

...

9 CYCL CALL

...

13 CYCL DEF 23 FINISARE PROFUNZIME

...

14 CYCL CALL

...

16 CYCL DEF 24 FINISARE LATERALA

...

17 CYCL CALL

...

50 L Z+250 R0 FMAX M2

51 END PGM CONT MM

 
Tip
  • Note de programare:
  • Capacitatea de memorie pentru programarea unui ciclu SL (toate programele de descriere a conturului) este limitată la 128 de contururi. Numărul de elemente de contur posibile depinde de tipul conturului (contur exterior sau interior) şi de numărul de descrieri de contur. Puteţi programa până la 16384 de elemente de contur.
  • Pentru a utiliza cicluri SL cu formule de contur, este obligatoriu ca programul dvs. să fie structurat cu grijă. Aceste cicluri vă permit să salvaţi contururile frecvent utilizate în programe NC separate. Utilizând o formulă de contur, puteţi conecta subcontururile la un contur complet şi puteţi defini dacă acesta este aplicat pentru un buzunar sau pentru o insulă.
  • Proprietăţile subcontururilor
  • Sistemul de control consideră conturul ca fiind un buzunar. Astfel, nu programaţi o compensare a razei.
  • Sistemul de control ignoră vitezele de avans F şi diversele funcţii M.
  • Transformările coordonatelor sunt permise – dacă sunt programate în cadrul subconturului, acestea sunt aplicate şi în programele NC apelate ulterior. Totuşi ele nu trebuie resetate după apelarea ciclului.
  • Deşi programele NC apelate pot conţine coordonate pe axa broşei, astfel de coordonate sunt ignorate.
  • Planul de lucru este definit în primul bloc de coordonate al programului NC.
  • Subcontururile pot fi definite cu adâncimi diferite, în funcţie de necesităţi.
  • Proprietăţile ciclului
  • Sistemul de control poziţionează automat scula la prescrierea de degajare înainte de un ciclu.
  • Fiecare nivel al adâncimii de avans este frezat fără întreruperi; freza avansează transversal în jurul insulelor şi nu pe deasupra lor.
  • Raza colţurilor interioare poate fi programată; scula nu se va opri, marcajele de temporizare sunt evitate (acest lucru se aplică traseului exterior de degroşare sau operaţiunilor de finisare laterală)
  • Conturul este abordat pe un arc tangenţial pentru finisarea laterală.
  • Pentru finisarea bazei, scula se apropie din nou de piesa de prelucrat pe un arc tangenţial (pentru axa sculei Z, de exemplu, arcul este în planul Z/X).
  • Conturul este prelucrat prin frezare în sensul avansului sau în sens contrar avansului.

Dimensiunile de prelucrare, precum adâncimea de frezare, toleranţele şi înălţimea de degajare, pot fi introduse central în Ciclul 20 DATE CONTUR sau 271 DATE CONTUR OCM.

Structură program: Calcularea de subcontururi cu formula de contur

0 BEGIN MODEL MM

1 DECLARE CONTOUR QC1 = "120"

2 DECLARE CONTOUR QC2 = "121" DEPTH15

3 DECLARE CONTOUR QC3 = "122" DEPTH10

4 DECLARE CONTOUR QC4 = "123" DEPTH5

5 QC10 = ( QC1 | QC3 | QC4 ) \ QC2

6 END PGM MODEL MM

0 BEGIN PGM 120 MM

1 CC X+75 Y+50

2 LP PR+45 PA+0

3 CP IPA+360 DR+

4 END PGM 120 MM

0 BEGIN PGM 121 MM

...

Selectarea unui program NC cu definiţie de contur

Cu funcţia SEL CONTUR selectaţi un program NC cu definiţii de contur, din care sistemul de control extrage descrierile conturului:

Procedați după cum urmează:

  1. Selectați Inserați funcția NC
  2. Sistemul de control deschide fereastra Inserați funcția NC.

  1. Selectați SEL CONTUR
  2. Sistemul de control deschide o fereastră de dialog pentru introducerea formulei de contur.
  3. Definirea conturului

Puteţi introduce contururile în următoarele moduri:

Setare posibilă

Funcție

Fişier

  • Introducere
  • Selecţie fişier

Definiţi numele conturului sau selectați Selectare fișier

QS

Definiţi numărul unui parametru şir

 
Tip
  • Note de programare:
  • Dacă un fişier apelat se află în acelaşi director ca cel din care apelaţi, puteţi să integraţi numele fişierului şi fără cale.
  • Programaţi un bloc SELECTARE CONTUR înaintea ciclurilor SL. Ciclul 14 GEOMETRIE CONTUR nu mai este necesar dacă utilizaţi SEL CONTUR.

Definirea unei descrieri a conturului

Cu funcţia DECLARARE CONTUR introduceţi într-un program NC calea programelor NC din care sistemul de control preia descrierile de contur. În plus, puteţi selecta o adâncime separată pentru această descriere a conturului.

Procedați după cum urmează:

  1. Selectați Inserați funcția NC
  2. Sistemul de control deschide fereastra Inserați funcția NC.

  1. Selectați DECLARARE CONTUR
  2. Sistemul de control deschide o fereastră de dialog pentru introducerea formulei de contur.
  3. Introduceţi numărul indicatorului de contur QC
  4. Definirea unei descrieri a conturului

Puteţi introduce contururile în următoarele moduri:

Setare posibilă

Funcție

Fişier

  • Introducere
  • Selecţie fişier

Definiţi numele conturului sau selectați Selectare fișier

QS

Definiţi numărul unui parametru şir

 
Tip
  • Note de programare:
  • Cu indicatorii de contur introduşi QC puteţi include diverse contururi în formula de contur.
  • Dacă un fişier apelat se află în acelaşi director ca cel din care apelaţi, puteţi să integraţi numele fişierului şi fără cale.
  • Dacă programaţi adâncimi separate pentru contururi, atunci trebuie să asignaţi o adâncime la toate subcontururile (asignaţi adâncimea 0, dacă este cazul).
  • Sistemul de control va lua în considerare înălţimile diferite (ADÂNCIME) numai dacă elementele se suprapun. Acest lucru nu este valabil în cazul insulelor propriu-zise din interiorul unui buzunar. Utilizaţi o formulă de contur simplă în acest scop.
  • Formula de contur simplă

Introducerea unei formule complexe de contur

Puteţi utiliza funcția formulei de contur pentru a interconecta diverse contururi într-o formulă matematică.

  1. Selectați Inserați funcția NC
  2. Sistemul de control deschide fereastra Inserați funcția NC.

  1. Selectaţi Formula ptr. contur QC
  2. Sistemul de control deschide o fereastră de dialog pentru introducerea formulei de contur.
  3. Introduceţi numărul indicatorului de contur QC
  4. Introducerea unei formule de contur

Grafică asistență

Introducere

Funcţie matematică

Exemplu

&

Intersectat cu

QC10 = QC1 & QC5

|

Reunit cu

QC25 = QC7 | QC18

^

Reunit cu, dar fără intersecţie

QC12 = QC5 ^ QC25

\

Fără

QC25 = QC1 \ QC2

(

Paranteză de deschidere

QC12 = QC1 şi (QC2 | QC3)

)

Paranteză de închidere

QC12 = QC1 şi (QC2 | QC3)

Definirea unui singur contur

QC12 = QC1

Contururi suprapuse

În mod prestabilit, sistemul de control consideră un contur programat ca fiind un buzunar. Cu funcţiile formulei de contur, puteţi transforma un contur dintr-un buzunar într-o insulă.

Buzunarele şi insulele pot fi suprapuse pentru a forma un contur nou. Puteţi aşadar mări suprafaţa unui buzunar cu un alt buzunar sau să o reduceţi cu o insulă.

Subprograme: buzunare suprapuse

 
Tip

Următoarele exemple reprezintă programe de descriere contur, definite într-un program de definire contur. Programul definire contur este apelat prin funcţia SELECTARE CONTUR în programul principal efectiv.

Buzunarele A şi B se suprapun.

Sistemul de control calculează punctele de intersecţie S1 şi S2 (nu trebuie programate).

Buzunarele sunt programate ca cercuri complete.

Program de descriere contur 1: buzunar A

0 BEGIN PGM POCKET MM

1 L X+10 Y+50 R0

2 CC X+35 Y+50

3 C X+10 Y+50 DR-

4 END PGM POCKET MM

Program de descriere contur 2: buzunar B

0 BEGIN PGM POCKET2 MM

1 L X+90 Y+50 R0

2 CC X+65 Y+50

3 C X+90 Y+50 DR-

4 END PGM POCKET2 MM

Suprafaţa de includere

Ambele suprafeţe A şi B trebuie să fie prelucrate, inclusiv suprafaţa suprapusă:

  • Suprafeţele A şi B trebuie să fi fost programate în programe NC separate, fără compensarea razei.
  • În formula de contur, suprafeţele A şi B sunt procesate cu funcţia "îmbinat cu".

Program definire contur:

* - ...

21 DECLARE CONTOUR QC1 = "POCKET.H"

22 DECLARE CONTOUR QC2 = "POCKET2.H"

23 QC10 = QC1 | QC2

* - ...

Suprafaţa de excludere

Suprafaţa A trebuie să fie prelucrată fără porţiunea suprapusă de B:

  • Suprafeţele A şi B trebuie programate în programe NC separate, fără compensarea razei.
  • În formula de contur, suprafaţa B este scăzută din suprafaţa A cu funcţia fără.

Program definire contur:

* - ...

21 DECLARE CONTOUR QC1 = "POCKET.H"

22 DECLARE CONTOUR QC2 = "POCKET2.H"

23 QC10 = QC1 \ QC2

* - ...

Suprafaţa de intersecţie

Trebuie prelucrată numai suprafaţa unde A şi B se suprapun. (Suprafeţele acoperite numai de A sau B nu trebuie prelucrate).

  • Suprafeţele A şi B trebuie programate în programe NC separate, fără compensarea razei.
  • În formula de contur, suprafeţele A şi B sunt procesate cu funcţia "intersecţie cu".

Program definire contur:

* - ...

21 DECLARE CONTOUR QC1 = "POCKET.H"

22 DECLARE CONTOUR QC2 = "POCKET2.H"

23 QC10 = QC1 & QC2

* - ...

Prelucrarea contururilor cu ciclurile SL sau OCM