Formule complexe de contour

Principes de base

Les formules de contour complexes permettent de construire des contours complexes en combinant plusieurs contours partiels (poches ou îlots). Les différentes sections de contour (données géométriques) se programment sous forme de programmes CN distincts. Ceci permet de réutiliser à volonté par la suite tous les contours partiels. À partir des contours partiels sélectionnés, reliés entre eux par une formule de contour, la CN calcule le contour en entier.

Schéma : usinage avec les cycles SL et formule complexe de contour

0 BEGIN CONT MM

...

5 SEL CONTOUR "MODEL"

6 CYCL DEF 20 DONNEES DU CONTOUR

...

8 CYCL DEF 21 EVIDEMENT

...

9 CYCL CALL

...

13 CYCL DEF 23 FINITION EN PROF.

...

14 CYCL CALL

...

16 CYCL DEF 24 FINITION LATERALE

...

17 CYCL CALL

...

50 L Z+250 R0 FMAX M2

51 END PGM CONT MM

 
Tip
  • Remarques concernant la programmation :
  • La mémoire est limitée à maximum 128 contours pour un cycle SL (tous les programmes de description de contour). Le nombre des éléments de contour possibles dépend du type de contour (contour interne/externe) ainsi que du nombre des descriptions de contour qui est au maximum de 16384 éléments.
  • Les cycles SL avec formule de contour imposent d'avoir un programme structuré, mais permettent d'intégrer dans différents programmes CN des contours qui reviennent régulièrement. Au moyen de la formule de contour, vous liez entre eux les contours partiels pour obtenir un contour final et définissez s'il s'agit d'une poche ou d'un îlot.
  • Caractéristiques des contours partiels
  • La commande détecte tous les contours comme poche. Ne programmez pas de correction de rayon.
  • La commande ignore les avances F et les fonctions auxiliaires M.
  • Les conversions de coordonnées sont autorisées – si celles-ci sont programmées dans les contours partiels, elles agissent également dans les programmes CN appelés suivants ; elles n'ont toutefois pas besoin d'être réinitialisées après l'appel du cycle.
  • Les programmes CN appelés peuvent aussi contenir des coordonnées dans l'axe de broche, mais celles-ci sont ignorées.
  • Vous définissez le plan d'usinage dans la première séquence de coordonnées du programme CN.
  • Si nécessaire, vous pouvez définir différentes profondeurs pour les contours partiels
  • Caractéristiques des cycles
  • Avant chaque cycle, la commande positionne automatiquement l'outil à la distance d'approche.
  • Chaque niveau de profondeur est fraisé sans relever l'outil ; les îlots sont contournés latéralement.
  • Le rayon des "angles intérieurs" est programmable. L'outil ne reste pas immobile, les marques de brise-copeaux sont évitées (vaut pour la trajectoire la plus externe lors de l'évidement et de la finition latérale).
  • En cas de finition latérale, la commande déplace l'outil sur une trajectoire circulaire tangentielle.
  • En cas de finition en profondeur, la commande déplace également l'outil selon une trajectoire circulaire jusqu'à la pièce (par ex. : axe de la broche Z : trajectoire circulaire dans le plan Z/X).
  • La commande usine le contour en continu, en avalant ou en opposition.

Les cotes d'usinage telles que la profondeur de fraisage, les surépaisseurs et la distance d'approche sont renseignées de manière centralisée dans le cycle 20 DONNEES DU CONTOUR ou 271 DONNEES CONTOUR OCM.

Schéma : calcul des contours partiels avec formule de contour

0 BEGIN MODEL MM

1 DECLARE CONTOUR QC1 = "120"

2 DECLARE CONTOUR QC2 = "121" DEPTH15

3 DECLARE CONTOUR QC3 = "122" DEPTH10

4 DECLARE CONTOUR QC4 = "123" DEPTH5

5 QC10 = ( QC1 | QC3 | QC4 ) \ QC2

6 END PGM MODEL MM

0 BEGIN PGM 120 MM

1 CC X+75 Y+50

2 LP PR+45 PA+0

3 CP IPA+360 DR+

4 END PGM 120 MM

0 BEGIN PGM 121 MM

...

Sélectionner un programme CN avec la définition de contour

Utiliser la fonction SEL CONTOUR pour sélectionner un programme CN contenant des définitions de contours à partir desquelles la commande extrait les descriptions de contours :

Procédez comme suit :

  1. Sélectionner Insérer fonction CN
  2. La CN ouvre la fenêtre Insérer fonction CN.

  1. Sélectionner SEL CONTOUR
  2. La commande lance la programmation de la formule de contour.
  3. Définition du contour

La CN propose les options suivantes pour la programmation de contour :

Option de sélection

Fonction

Fichier

  • Programmation
  • Sélection de fichier

Définir le nom du contour ou opter pour la sélection de fichier

QS

Définir le numéro d'un paramètre string

 
Tip
  • Remarques concernant la programmation :
  • Si le fichier appelé se trouve dans le même répertoire que le fichier appelant, vous pouvez alors vous contenter de renseigner le nom du fichier, sans le chemin.
  • Programmer la séquence SEL CONTOUR avant les cycles SL. Le cycle 14 CONTOUR n'est plus nécessaire si vous utilisez SEL CONTUR.

Définir une description de contour

La fonction DECLARE CONTOUR vous permet d'attribuer à un programme CN le chemin des programmes CN à partir desquels la commande extrait les descriptions de contours. Vous pouvez en outre sélectionner une profondeur distincte pour la description de contour.

Procédez comme suit :

  1. Sélectionner Insérer fonction CN
  2. La CN ouvre la fenêtre Insérer fonction CN.

  1. Sélectionner DECLARE CONTOUR
  2. La commande lance la programmation de la formule de contour.
  3. Entrer l'identifiant du contour QC
  4. Définir une description de contour

La CN propose les options suivantes pour la programmation de contour :

Option de sélection

Fonction

Fichier

  • Programmation
  • Sélection de fichier

Définir le nom du contour ou opter pour la sélection de fichier

QS

Définir le numéro d'un paramètre string

 
Tip
  • Remarques concernant la programmation :
  • Grâce aux indicatifs de contour QC que vous avez introduits, vous pouvez relier entre eux les différents contours dans la formule de contour.
  • Si le fichier appelé se trouve dans le même répertoire que le fichier appelant, vous pouvez alors vous contenter de renseigner le nom du fichier, sans le chemin.
  • Si vous utiliser des contours avec profondeur séparée, vous devez alors attribuer une profondeur à tous les contours partiels (si nécessaire, indiquer la profondeur 0).
  • Différentes profondeurs (DEPTH) ne sont prises en compte que pour les éléments qui se chevauchent. Ceci n'est pas le cas pour les îlots purs d'une poche. Utilisez pour cela la formule de contour simple.
  • Formule simple de contour

Introduire une formule complexe de contour

La fonction Formule de contour vous permet de connecter entre eux différents contours dans une formule mathématique :

  1. Sélectionner Insérer fonction CN
  2. La CN ouvre la fenêtre Insérer fonction CN.

  1. Sélectionnez la Formule de contour QC
  2. La commande lance la programmation de la formule de contour.
  3. Entrer l'identifiant du contour QC
  4. Entrer la formule de contour

Figure d'aide

Programmation

Fonction de liaison

Exemple

&

En intersection avec

QC10 = QC1 & QC5

|

Réuni avec

QC25 = QC7 | QC18

^

Réuni avec, mais sans intersection

QC12 = QC5 ^ QC25

\

Sans

QC25 = QC1 \ QC2

(

Parenthèse ouverte

QC12 = QC1 & (QC2 | QC3)

)

Parenthèse fermée

QC12 = QC1 & (QC2 | QC3)

Définir un contour individuel

QC12 = QC1

Contours superposés

La commande considère un contour programmé comme étant une poche. Grâce aux fonctions de formule de contour, vous pouvez convertir un contour en îlot.

Un nouveau contour peut être construit en superposant des poches et des îlots. De cette manière, vous pouvez agrandir la surface d'une poche par superposition d'une autre poche ou la réduire avec un îlot.

Sous-programmes : poches superposées

 
Tip

Les exemples de programmation suivants correspondent à des programmes avec description de contour qui sont définis dans un programme de définition de contour. Le programme de définition de contour doit lui-même être appelé dans le programme principal avec la fonction SEL CONTOUR.

Les poches A et B se superposent.

La commande calcule les points d’intersection S1 et S2. Vous n'avez donc pas besoin de les programmer.

Les poches sont programmées comme des cercles entiers.

Programme de description de contour 1: Poche A

0 BEGIN PGM POCKET MM

1 L X+10 Y+50 R0

2 CC X+35 Y+50

3 C X+10 Y+50 DR-

4 END PGM POCKET MM

Programme de description de contour 2 : poche B

0 BEGIN PGM POCKET2 MM

1 L X+90 Y+50 R0

2 CC X+65 Y+50

3 C X+90 Y+50 DR-

4 END PGM POCKET2 MM

Surface „d'addition“

Les deux surfaces partielles A et B, y compris leurs surfaces communes, doivent être usinées :

  • Les surfaces A et B doivent être programmées dans des programmes CN distincts, sans correction de rayon.
  • Dans la formule de contour, les surfaces A et B sont prises en compte avec la fonction “réuni avec“

Programme de définition de contour :

* - ...

21 DECLARE CONTOUR QC1 = "POCKET.H"

22 DECLARE CONTOUR QC2 = "POCKET2.H"

23 QC10 = QC1 | QC2

* - ...

Surface „de soustraction“

La surface A doit être usinée sans la partie recouverte par B:

  • Les surfaces A et B doivent être programmées dans des programmes CN distincts, sans correction de rayon.
  • Dans la formule de contour, la surface B est soustraite de la surface A avec la fonction sans.

Programme de définition de contour :

* - ...

21 DECLARE CONTOUR QC1 = "POCKET.H"

22 DECLARE CONTOUR QC2 = "POCKET2.H"

23 QC10 = QC1 \ QC2

* - ...

Surface „d'intersection“

La surface commune de recouvrement de A et de B doit être usinée. (Les surfaces sans recouvrement ne doivent pas être usinées.)

  • Les surfaces A et B doivent être programmées dans des programmes CN distincts, sans correction de rayon.
  • Dans la formule de contour, les surfaces A et B sont prises en compte avec la fonction “intersection avec“

Programme de définition de contour :

* - ...

21 DECLARE CONTOUR QC1 = "POCKET.H"

22 DECLARE CONTOUR QC2 = "POCKET2.H"

23 QC10 = QC1 & QC2

* - ...

Usinage du contour avec les cycles SL ou OCM

 
Tip

L'usinage du contour global défini s'effectue avec les cycles SL ou avec les cycles OCM (voir Vue d’ensemble).