Monimutkainen muotokaava

Perusteet

Monimutkaisilla muotokaavoilla voit yhdistää monimutkaisia muotoja osamuodoista (taskuista tai saarekkeista). Yksittäiset osamuodot (geometriatiedot) syötetään sisään erillisinä NC-ohjelmina. Näin kaikkia osamuotoja voidaan käyttää edelleen mielivaltaisella tavalla. Ohjaus laskee kokonaismuodon valituista osamuodoista, jotka liität yhteen muotokaavan avulla.

sl_contform_depth
Aihe: Koneistus SL-työkierroilla ja monimutkaisilla muotokaavoilla

0 BEGIN CONT MM

5 SEL CONTOUR "MODEL"

6 CYCL DEF 20 MUODON TIEDOT

8 CYCL DEF 21 ROUHINTA

9 CYCL CALL

13 CYCL DEF 23 POHJAN VIIMEISTELY

14 CYCL CALL

16 CYCL DEF 24 REUNAN VIIMEISTELY

17 CYCL CALL

...

50 L Z+250 R0 FMAX M2

51 END PGM CONT MM

 
Tip
  • Ohjelmointiohjeet:
  • SL-työkiertojen muistitila (kaikki muotokuvausohjelmat) on rajoitettu käsittämään enintään 128 muotoa. Muotoelementtien mahdollinen lukumäärä riippuu muototavasta (sisä- tai ulkomuoto) ja osamuotojen lukumäärästä ja on suuruudeltaan enintään 16384 muotoelementtiä.
  • SL-työkierrot muotokaavoilla edellyttävät strukturoitua ohjelmarakennetta ja antavat mahdollisuuden sijoittaa usein toistuvia muotoja yksittäisiin NC-ohjelmiin. Muotokaavojen avulla yhdistetään osamuodot kokonaismuotoon ja määritellään, onko kyseessä tasku vai saareke.
  • Osamuotojen ominaisuudet
  • Ohjaus tunnistaa kaikki muodot taskuiksi. Älä ohjelmoi sädekorjausta.
  • Ohjaus jättää huomiotta syöttöarvon F ja lisätoiminnot M.
  • Koordinaattimuunnokset ovat sallittuja – Kun se ohjelmoidaan osamuotojen sisällä, se vaikuttaa myös myöhemmissä NC-ohjelmissa, tosin sitä ei täydy peruuttaa työkierron kutsun jälkeen.
  • Kutsutut NC-ohjelmat saavat sisältää kara-akselin koordinaatteja, tosin ne jätetään huomiotta.
  • Kutsutun NC-ohjelman ensimmäisessä koordinaattilauseessa määritellään koneistustaso.
  • Tarvittaessa voit määritellä osamuodot erilaisilla syvyyksillä.
  • Työkiertojen ominaisuudet
  • Ohjaus paikoittuu ennen jokaista työkiertoa automaattisesti varmuusetäisyydelle.
  • Jokainen syvyystaso jyrsitään ilman työkalun poistoa; saarekkeet ajetaan sivuttain ympäri.
  • „Sisänurkkien säde“ voidaan ohjelmoida – työkalu ei jää paikalleen, jyrsinterän jäljet estetään (koskee vain ulointa rataa rouhinnassa ja sivun silityksessä).
  • Sivun silityksessä ohjaus ajaa muotoon ympyrärataa tangentiaalisella liitynnällä.
  • Syvyyssilityksessä ohjaus ajaa työkalun niinikään ympyräkaaren mukaista rataa tangentiaalisellaliitynnällä työkappaleeseen (esim.: kara-akseli Z: ympyräkaarirata tasossa Z/X)
  • Ohjaus koneistaa muodon ympäriinsä myötälastulla tai vastalastulla.

Koneistuksen mittamäärittelyt, kuten jyrsintäsyvyys, työvara ja varmuusetäisyys, määritellään työkierrossa 20 MUODON TIEDOT tai 271 OCM MUOTOTIEDOT.

Aihe: Osamuodon käsittely muotokaavalla

0 BEGIN MODEL MM

1 DECLARE CONTOUR QC1 = "120"

2 DECLARE CONTOUR QC2 = "121" DEPTH15

3 DECLARE CONTOUR QC3 = "122" DEPTH10

4 DECLARE CONTOUR QC4 = "123" DEPTH5

5 QC10 = ( QC1 | QC3 | QC4 ) \ QC2

6 END PGM MODEL MM

0 BEGIN PGM 120 MM

1 CC X+75 Y+50

2 LP PR+45 PA+0

3 CP IPA+360 DR+

4 END PGM 120 MM

0 BEGIN PGM 121 MM

NC-ohjelman valinta muotomäärittelyllä

Toiminnolla SEL CONTOUR valitaan NC-ohjelma ja muotomäärittelyt, joista ohjaus ottaa muotokuvaukset:

Toimi sen jälkeen seuraavasti:

SF_4_NCFunktion_Einfuegen

  1. Valitse NC-toiminnon lisäys.
  2. Ohjaus avaa ikkunan NC-toiminnon lisäys.
SelectContour

  1. Valitse SEL CONTOUR.
  2. Ohjaus käynnistää muotokaavan sisäänsyötön.
  3. Muodon määrittely

Ohjaus tarjoaa muodon sisäänsyöttöön seuraavat mahdollisuudet:

Valintamahdollisuus

Toiminto

Tiedosto

  • Sisäänsyöttö
  • Tiedostonvalinta

Muodon nimen määrittely tai tiedostonvalinnan valinta

QS

Merkkijonoparametrin numeron määrittely

 
Tip
  • Ohjelmointiohjeet:
  • Jos kutsuttava tiedosto on samassa hakemistossa kuin kutsuva tiedosto, voi määritellä tiedostonimen myös ilman polkua, esim.
  • Ohjelmoi SEL CONTOUR-lause ennen SL-työkiertoja. Työkiertoa 14 MUOTO ei enää tarvita käytettäessä SEL CONTUR -lausetta.

Muotokuvauksen määrittely

Toiminnolla DECLARE CONTOUR syötetään sisään NC-ohjelman polku sille NC-ohjelmalle, josta ohjaus ottaa muotokuvaukset. Lisäksi tälle muotokuvaukselle voidaan valita syvyys erikseen.

Toimi sen jälkeen seuraavasti:

SF_4_NCFunktion_Einfuegen

  1. Valitse NC-toiminnon lisäys.
  2. Ohjaus avaa ikkunan NC-toiminnon lisäys.

  1. Valitse DECLARE CONTOUR.
  2. Ohjaus käynnistää muotokaavan sisäänsyötön.
  3. Syötä sisään muototunnuksen QC numero, vahvista näppäimellä ENT.
  4. Muotokuvauksen määrittely

Ohjaus tarjoaa muodon sisäänsyöttöön seuraavat mahdollisuudet:

Valintamahdollisuus

Toiminto

Tiedosto

  • Sisäänsyöttö
  • Tiedostonvalinta

Muodon nimen määrittely tai tiedostonvalinnan valinta

QS

Merkkijonoparametrin numeron määrittely

 
Tip
  • Ohjelmointiohjeet:
  • Määritellyillä muototunnuksilla QC voidaan muotokaavassa käsitellä keskenään erilaisia muotoja.
  • Jos kutsuttava tiedosto on samassa hakemistossa kuin kutsuva tiedosto, voi määritellä tiedostonimen myös ilman polkua, esim.
  • Jos käytät muotoja eri syvyyksillä, täytyy syvyys silloin määritellä kaikille osamuodoille erikseen (tarv. määrittele syvyys 0).
  • Eri syvyyksiä (DEPTH) lasketaan vain päällekkäisillä elementeillä. Näin ei kuitenkaan tapahdu taskun sisäpuolisilla puhtailla saarekkeilla. Käytä sitä varten yksinkertaista muotokaavaa.
  • Yksinkertainen muotokaava

Syötä sisään monipuolinen muotokaava

Muotokaavatoiminnon avulla voi ketjuttaa yhteen erilaisia muotoja matemaattisessa kaavassa.

SF_4_NCFunktion_Einfuegen

  1. Valitse NC-toiminnon lisäys.
  2. Ohjaus avaa ikkunan NC-toiminnon lisäys.

  1. Valitse Muotokaava QC.
  2. Ohjaus käynnistää muotokaavan sisäänsyötön.
  3. Syötä sisään muototunnuksen QC numero, vahvista näppäimellä ENT.
  4. Syötä sisään muotokaava

Apukuva

Sisäänsyöttö

Ketjutustoiminto

Esimerkki

8H000166

&

Leikkaus

QC10 = QC1 & QC5

8H000164

|

Unioni

QC25 = QC7 | QC18

Konturformel_Funktion3

^

Unioni ilman leikkausta

QC12 = QC5 ^ QC25

8H000165

\

ilman

QC25 = QC1 \ QC2

(

Sulku auki

QC12 = QC1 & (QC2 | QC3)

)

Sulku kiinni

QC12 = QC1 & (QC2 | QC3)

Yksittäisen muodon määrittely

QC12 = QC1

Päällekkäiset muodot

8H000164

Ohjaus käsittää ohjelmoidun muodon taskuksi. Muotokaavan toiminnoilla voit muuntaa muodon saarekkeeksi.

Uuteen muotoon voidaan latoa päällekkäin taskuja ja saarekkeita. Näinollen päälle asetettu tasku voi suurentaa tai saareke pienentää toisen taskun tasopintaa.

Aliohjelmat: Päällekkäiset taskut

 
Tip

Seuraavat esimerkit ovat muotokuvausohjelmia, jotka määritellään muotokuvausohjelmassa. Muotokuvausohjelma kutsutaan edelleen toiminnolla SEL CONTOUR varsinaisessa pääohjelmassa.

Taskut A ja B ovat päällekkäin.

Ohjaus laskee leikkauspisteet S1 ja S2, niitä ei tarvitse ohjelmoida.

Taskut on ohjelmoitu täysiympyröinä.

Muotokuvausohjelma 1: Tasku A

0 BEGIN PGM POCKET MM

1 L X+10 Y+50 R0

2 CC X+35 Y+50

3 C X+10 Y+50 DR-

4 END PGM POCKET MM

Muotokuvausohjelma 2: Tasku B

0 BEGIN PGM POCKET2 MM

1 L X+90 Y+50 R0

2 CC X+65 Y+50

3 C X+90 Y+50 DR-

4 END PGM POCKET2 MM

„Summa“-pinta

8H000164

Koneistetaan molemmat osapinnat A ja B sekä yhteinen päällekkäinen pinta:

  • Pintojen A ja B on oltava ohjelmoitu erillisissä NC-ohjelmissa ilman sädekorjausta
  • Muotokaavassa pinnat A ja B käsitellään “unionitoiminnolla”.

Muodonmäärittelyohjelma:

* - ...

21 DECLARE CONTOUR QC1 = "POCKET.H"

22 DECLARE CONTOUR QC2 = "POCKET2.H"

23 QC10 = QC1 | QC2

* - ...

„Erotus“-pinta

8H000165

Pinta A koneistetaan ilman pinnan B:n kanssa yhteistä päällekkäistä osuutta:

  • Pintojen A ja B on oltava ohjelmoitu erillisissä NC-ohjelmissa ilman sädekorjausta
  • Muotokaavassa pinta B erotetaan pinnasta A toiminnolla ilman.

Muodonmäärittelyohjelma:

* - ...

21 DECLARE CONTOUR QC1 = "POCKET.H"

22 DECLARE CONTOUR QC2 = "POCKET2.H"

23 QC10 = QC1 \ QC2

* - ...

„Leikkaus“-pinta

8H000166

Koneistetaan A:n ja B:n yhteinen päällekkäinen pintaosuus. (Yksinkertaisesti ulkopuoliset pinnat jätetään koneistamatta.)

  • Pintojen A ja B on oltava ohjelmoitu erillisissä NC-ohjelmissa ilman sädekorjausta
  • Muotokaavassa pinnat A ja B käsitellään toiminnolla “leikkaus”.

Muodonmäärittelyohjelma:

* - ...

21 DECLARE CONTOUR QC1 = "POCKET.H"

22 DECLARE CONTOUR QC2 = "POCKET2.H"

23 QC10 = QC1 & QC2

* - ...

Muodon toteutus SL tai OCM-työkierroilla

 
Tip

Kokonaismuodon koneistus toteutetaan SL-työkierroilla tai OCM-työkierroilla (katso Yleiskuvaus).