Exemplu: Găurire automată, degroşare şi finisarea contururilor suprapuse cu Cicluri SL

8H000B13

Programele NC conținute în Manualul utilizatorului reprezintă sugestii de soluții. Programele NC sau blocurile NC individuale trebuie adaptate înainte de a fi utilizate la nivelul mașinii.

  • Modificați următorul conținut după cum este necesar:
  • Scule
  • Parametri de tăiere
  • Viteze de avans
  • Înălțimea de degajare sau poziția de siguranță
  • Pozițiile specifice mașinii, de ex., cu M91
  • Traseele apelărilor programului

Anumite programe NC depind de cinematica mașinii. Adaptați aceste programe NC la cinematica mașinii dvs. înainte de prima rulare a testului.

În plus, testați programele NC utilizând simularea înainte de rularea efectivă a programului.

 
Tip

Cu o testare a programului, puteți determina dacă programul NC poate fi utilizat cu opțiunile de software disponibile, cu cinematica mașinii active și cu configurația curentă a mașinii.

0 BEGIN PGM 2 MM

1 BLK FORM 0.1 Z X+0 Y+0 Z-40

2 BLK FORM 0.2 X+100 Y+100 Z+0

3 TOOL CALL 204 Z S2500

; Apelare sculă: găurire (diametru: 12)

4 L Z+250 R0 FMAX M3

; Retragere sculă

5 CYCL DEF 14.0 GEOMETRIE CONTUR

6 CYCL DEF 14.1 ETICH. CONTUR1 /2 /3 /4

7 CYCL DEF 20 DATE CONTUR ~

Q1=-20

;ADANCIME FREZARE ~

Q2=+1

;SUPRAP. CALE UNEALTA ~

Q3=+0.5

;ADAOS LATERAL ~

Q4=+0.5

;ADAOS ADANCIME ~

Q5=+0

;COORDONATA SUPRAFATA ~

Q6=+2

;DIST. DE SIGURANTA ~

Q7=+100

;CLEARANCE HEIGHT ~

Q8=+0.1

;RAZA ROTUNJIRE ~

Q9=-1

;DIRECTIE ROTATIE

8 CYCL DEF 21 GAURIRE AUTOMATA ~

Q10=-5

;ADANCIME PLONJARE ~

Q11=+150

;VIT. AVANS PLONJARE ~

Q13=+0

;UNEALTA TAIERE

9 CYCL CALL

; Apelare ciclu: găurire automată

10 L Z+100 R0 FMAX

; Retragere sculă

11 TOOL CALL 6 Z S3000

; Apelare sculă: degroşare/finisare (D12)

12 CYCL DEF 22 DEGROSARE ~

Q10=-5

;ADANCIME PLONJARE ~

Q11=+100

;VIT. AVANS PLONJARE ~

Q12=+350

;VITEZA AVANS DEGROS. ~

Q18=+0

;UNEALTA DEGR. GROS. ~

Q19=+150

;VIT.AV.MISC.RECT.ALT ~

Q208=+99999

;VIT. AVANS RETRAGERE ~

Q401=+100

;FACTOR VITEZA AVANS ~

Q404=+0

;STRATEG. DEGROS.FINA

13 CYCL CALL

; Apelare ciclu: degroşare

14 CYCL DEF 23 FINISARE PROFUNZIME ~

Q11=+100

;VIT. AVANS PLONJARE ~

Q12=+200

;VITEZA AVANS DEGROS. ~

Q208=+99999

;VIT. AVANS RETRAGERE

15 CYCL CALL

; Apelare ciclu: finisare bază

16 CYCL DEF 24 FINISARE LATERALA ~

Q9=+1

;DIRECTIE ROTATIE ~

Q10=-5

;ADANCIME PLONJARE ~

Q11=+100

;VIT. AVANS PLONJARE ~

Q12=+400

;VITEZA AVANS DEGROS. ~

Q14=+0

;ADAOS LATERAL ~

Q438=-1

;UNEALTA TAIERE

17 CYCL CALL

; Apelare ciclu: finisare laterală

18 L Z+100 R0 FMAX

; Retragere sculă

19 M30

; Sfârşitul programului

20 LBL 1

; Subprogram de contur 1: buzunarul stâng

21 CC X+35 Y+50

22 L X+10 Y+50 RR

23 C X+10 DR-

24 LBL 0

25 LBL 2

; Subprogram de contur 2: buzunarul drept

26 CC X+65 Y+50

27 L X+90 Y+50 RR

28 C X+90 DR-

29 LBL 0

30 LBL 3

; Subprogram de contur 3: insulă pătrată stânga

31 L X+27 Y+50 RL

32 L Y+58

33 L X+43

34 L Y+42

35 L X+27

36 LBL 0

37 LBL 4

; Subprogram de contur 4: insulă triunghiulară dreapta

38 L X+65 Y+42 RL

39 L X+57

40 L X+65 Y+58

41 L X+73 Y+42

42 LBL 0

43 END PGM 2 MM